Portfolio

>>,>>>,>>,,<<<,>>,,>>>>>>,                                      Read test point and first two polygon points
[                                                               Until end of input
  [<<<<+>+>>>-]<<<[>>>+<<<-]                                    t0 = y2
  <<<<[>>>>+>+<<<<<-]>>>>>[<<<<<+>>>>>-]                        t1 = y
  <<[>>+<[>[-]>+<<-]>>[<<+>>-]<[<<[-]+<<<<<+>>>>>>>-]<-<-]>[-]  s2 = y2 greater than y
  <<<<<[>>>>+>+<<<<<-]>>>>>[<<<<<+>>>>>-]                       t0 = y1                                               
  <<<<[>>>>+>+<<<<<-]>>>>>[<<<<<+>>>>>-]                        t1 = y
  <<[>>+<[>[-]>+<<-]>>[<<+>>-]<[<<[-]+>>>>>+<<<-]<-<-]>[-]      s1 = y1 greater than y
  >>>>[<<<<+>>>>-]                                              t1 = s1
  <<<<<<<<<<[>>>>>>-<+<<<<<-]>>>>>[<<<<<+>>>>>-]>[>>>>+<<<<[-]] s1 = s1 != s2
  >>>>[-                                                        if (s1)
    <<<<<<[>+>+<<-]>>[<<+>>-]                                   t0 = x1
    <<<[>>>+>+<<<<-]>>>>[<<<<+>>>>-]                            t1 = x2 
    <<[>>+<[>[-]>+<<-]>>[<<+>>-]<[<<[-]+>>>>>+<<<-]<-<-]>[-]    s1 = x1 greater than x2 
    +>>>>[-<<<<-                                                if (s1)
      <<<[>>+<-<-]>>[<<+>>-]                                    x1 = x1 minus x2
    >>>>>]<<<<[-                                                else
      <<<[>>+>+<<<-]>>>[<<<+>>>-]<<[>-<-]>[<+>-]                x1 = x2 minus x1
    >]
    +<<<<<<[->>>>>>-                                            if (s2)
      >>>[<<<<+>+>>>-]<<<[>>>+<<<-]                             t0 = y2
      <<<<[>>>>+<-<<<-]>>>>[<<<<+>>>>-]                         t0 = y2 minus y
    <<<<<<]>>>>>>[-                                             else
      <<<<[>>>+>+<<<<-]>>>>[<<<<+>>>>-]                         t0 = y
      >>>[<<<+<->>>>-]<<<[>>>+<<<-]                             t0 = y minus y2
    ]
    <<[>>>+<<<-]                                                t2 = x1
    >>>[<<[>+<<+>-]>[<+>-]>-]<<[-]                              x1 = x1 * t0
    <<<<[>>>>+>+<<<<<-]>>>>>[<<<<<+>>>>>-]                      t0 = y1
    >>>[<<<+>+>>-]<<[>>+<<-]                                    t1 = y2
    <<[>>+<[>[-]>+<<-]>>[<<+>>-]<[<<[-]+>>>>>+<<<-]<-<-]>[-]    s1 = y1 greater than y2
    +>>>>[-<<<<-                                                if (s1)
      >>>[<<+<<<<<<->>>>>>>>-]<<[>>+<<-]                        y1 = y1 minus y2
    >>>]<<<<[-                                                  else
       >>>[<<<+<+>>>>-]                                         t0 = y2
       <<<<<<<<[>>>>-<<<<-]>>>>[<<<<+>>>>-]>[>>>+<<<-]          y1 = y2 minus y1
    ]
    <<[>+<-]                                                    t0 = x1
    >[<<<<[>>>>>+>+<<<<<<-]>>>>>>[<<<<<<+>>>>>>-]
    <[>+<<-[>>[-]>+<<<-]>>>[<<<+>>>-]<[<-[<<->>[-]]+>-]<-]<<+>] x1 = x1 / y1
    <<[>+>+<<-]>>[<<+>>-]                                       x1 = x1 plus x2
    <<<<<<[>>>>>>+>+<<<<<<<-]>>>>>>>[<<<<<<<+>>>>>>>-]          t0 = x
    <<[>>>+>+<<<<-]>>>[<<<+>>>-]                                t3 = x1  
    <<[>+<-]>>>[<<->+>-]<[>+<-]<[<+>[-]]                        t0 = x != x1
    +<[->-                                                      if (t0)
      <<<<<<<[>>>>>>+>+<<<<<<<-]>>>>>>>[<<<<<<<+>>>>>>>-]       t0 = x
      <[>>+>[<[-]<+>>-]<<[>>+<<-]>[<<[-]+<<<<<<<<[>>>+       
      <<<-]+>>>[<<<->>>-]>>>>>>>-]>-<<<-]>>>[-]<<<              c1 = x greater than x1 then !c2
      <<<<<<[>>>>>>+>+<<<<<<<-]>>>>>>>[<<<<<<<+>>>>>>>-]        t0 = x
      <<[>>>+<<[>>[-]<+<-]>[<+>-]>[<<<[-]+<<<<<<[>>+<<-]+         
      >>[<<->>-]>>>>>>>-]<<-<-]>[-]                             c2 = x less than x1 then !c2
    ]>[-                                                        else
      <<<<<<<<[>>+<<-]+>>[<<->>-]                               C2 = !C2
    >>>>>>]
  >>>>]
  <<<<<<[-]<<<[-]<[-]
  >>>[>+<-],,>>>>>>[<<<<<<<<+>>>>>>>>-],                        Copy (x2 y2) to (x1 y1) read (x2 y2)
]              
<<<<<<<<<<<<[>+<-]>[>>+<<[-]]>>[<<+>>-]                         c2 = c2 || c1
++++++++[<<++++++>>-]<<.                                        Print c

Brainfuck Interpreter

> Move pointer one memory location forward
< Move pointer one memory location backward
+ Increment data at memory location by one
- Decrement data at memory location by one
[ If memory location is 0, skip to ], else continue
] If memory location is 0, continue, else skip to [
, Read input character into memory location
. Write output character from memory location
$ Memory dump for debugging

Enable memory dump symbol
Automatic output conversion to ASCII
Signed Memory
Block size (bytes):
Memory size (blocks):

Brainfuck Interpreter

Memory Dumps